home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / mac / LOGIC Apple II 5.25" Library - ProDOS / PRO001.dsk / FIN / BOND.ANALYSIS.bas < prev    next >
BASIC Source File  |  2012-02-16  |  4KB  |  84 lines
  1. 0  HOME 
  2. 5  SPEED= 175
  3. 6  PRINT : PRINT "DESCRIPTION & USES ON PROGRAM START          AT LINE 555 TO 600";
  4. 7  PRINT : PRINT : PRINT 
  5. 8  PRINT : PRINT "ENTER YES, NO, OR DATA TO START";
  6. 9  PRINT : PRINT : PRINT 
  7. 15  REM  THIS BASIC PROGRAM COMPUTES THE PRICE AND ACCRUED INTEREST
  8. 20  REM  OF A BOND
  9. 22  REM 
  10. 25  REM  **********************************************
  11. 30  REM 
  12. 100  REM  THIS PROGRAM COMPUTES THE PRICE AND ACCRUED INTEREST FOR
  13. 110  REM  A BOND WITH A COUPON OF C DOLLARS A YEAR, REDEMPTION
  14. 120  REM  AT R DOLLARS, AND A MATURITY OF M1 YEARS AND M2
  15. 130  REM  MONTHS (M2 NEED NOT BE AN INTEGER), SELLING TO YIELD Y.
  16. 133  REM       **********         **************       ************
  17. 138  REM  LINE 150 CONTAINS SAMPLE DATA STATEMENTS.
  18. 140  REM  ************* MAIN PROGRAM **************
  19. 145  REM 
  20. 150  DATA  6,100,12,5,.055
  21. 160  REM 
  22. 170  PRINT "DO YOU WANT INSTRUCTIONS FOR ENTERING DATA";
  23. 180  INPUT A$
  24. 190  PRINT 
  25. 200  IF A$ = "DATA"  THEN 420
  26. 210  IF A$ = "NO"  THEN 370
  27. 220  PRINT "ENTER THE FOLLOWING ITEMS OF DATA"
  28. 230  PRINT 
  29. 240  PRINT "ITEM 1"; TAB( 12);"ANNUAL COUPON IN DOLLARS"; TAB( 40);
  30. 250  INPUT C
  31. 260  PRINT 
  32. 270  PRINT "ITEM 2"; TAB( 12);"PROCEEDS ON REDEMPTION"; TAB( 40);
  33. 280  INPUT R
  34. 290  PRINT 
  35. 300  PRINT "ITEMS 3 & 4"; TAB( 12);"MATURITY IN YEARS, MONTHS"; TAB( 40);
  36. 310  INPUT M1,M2
  37. 320  PRINT 
  38. 330  PRINT "ITEM 5"; TAB( 12);"YIELD TO MATURITY"; TAB( 40)
  39. 340  INPUT Y
  40. 350  PRINT 
  41. 360  GOTO 440
  42. 370  PRINT "ENTER ITEMS 1 THROUGH 5";
  43. 380  INPUT C,R,M1,M2,Y
  44. 390  PRINT 
  45. 400  GOTO 440
  46. 410  REM 
  47. 420  READ C,R,M1,M2,Y
  48. 430  DATA  6,100,12,5,.055
  49. 440  PRINT "COUPON";C,"REDEMPTION AT";R
  50. 450  PRINT "MATURITY",M1;"YEARS",M2;"MONTHS"
  51. 460  PRINT "YIELD";Y
  52. 470  PRINT 
  53. 478  REM  NUMBER OF COUPON PERIODS TO MATURITY
  54. 480  LET M3 = M1 *2 +M2/6
  55. 488  REM  NUMBER OF WHOLE COUPON PERIODS TO MATURITY
  56. 490  LET M4 =  INT(M3)
  57. 498  REM  TIME TO NEXT COUPON
  58. 500  LET M5 = M3 -M4
  59. 508  REM  PRESENT VALUE OF FUTURE COUPONS
  60. 510  LET V1 = C/2 *(1 -(1 +Y/2) ^( -M4))/(Y/2)
  61. 518  REM  P.V. OF PRINCIPAL AT TIME OF NEXT COUPON
  62. 520  LET V2 = R/(1 +Y/2) ^(M4)
  63. 528  REM  P.V. OF BOND NOW
  64. 530  LET P = (V1 +V2 +C/2)/((1 +Y/2) ^M5) -(C/2) *(1 -M5)
  65. 540  PRINT "PRICE",P,"ACCR INT",C/2 *(1 -M5)
  66. 550  END 
  67. 560  REM  **** BOND PROGRAM *****        
  68. 570  REM  DESCRIPTION
  69. 571  REM  THIS PROGRAM IS USED TO COMPUTE THE PRICE & ACCRUED INTEREST FOR BOND ACCOUNTING
  70. 572  REM  THE ACQUISITION COST OF A BOND INCLUDES ITS PURCHASE PRICE PLUS ITS ACCRUED INTEREST.
  71. 573  REM  IF THE PURCHASER HOLDS THE BOND UNTIL IT IS MATURE HE EXPECTS TO RECEIVE INTEREST PAYMENTS ON A REGULAR BASIS.
  72. 574  REM  THESE INTEREST PAYMENTS ARE CALLED "COUPON" PAYMENTS.
  73. 575  REM  AT MATURITY THE PRICE OF THE BOND IS CALLED "PAR" AND IS THE SAME AS THE FACE VALUE OF THE BOND.
  74. 576  REM  IN THE EVENT THE TERMS OF THE BOND ALLOW IT TO BE CALLED BEFORE MATURITY THE PURCHASER WILL ONLY RECEIVE INTEREST UP TO THE CALL DATE.
  75. 577  REM     USERS
  76. 578  REM  ANYONE WHO BUYS, SELLS, OR TRADES IN BONDS OF ANY NATURE COULD USE THIS PROGRAM.
  77. 579  REM  THIS WOULD INCLUDE BUSINESSMEN, WORKERS, HOUSEWIVES, RETIREES, ALMOST ANYONE WHO HAS MONEY TO INVEST.
  78. 580  REM     INSTRUCTIONS
  79. 581  REM  TYPE "RUN"; THE PROGRAM WILL THEN ASK YOU IF YOU WANT INSTRUCTIONS.
  80. 582  REM  THERE ARE THREE POSSIBLE VALID RESPONSES TO THIS PROMPT.
  81. 583  REM   1. YES - IT WILL PRINT A DESCRIPTION OF THE DATA INPUTS.
  82. 584  REM   2. NO - IT WILL ASK FOR THE FIVE INPUTS.
  83. 585  REM   3. DATA - IT WILL PRINT WHAT DATA IS PRESENT IN THE PROGRAM.
  84. 586  REM  ALL DATA IS EXPRESSES PER HUNDRED DOLLARS PER BOND VALUE.